11.2 コマンドと例題プログラムの解説
目次へ戻る
- 例題のプログラムで使った多面体モデルは、第２章の例題プログラムROBOT.BAS で例示したロボットのアームの一部です。ロボットの腕の部分まで５、つの部品を使いました。
- 行番号240までは、モデルの生成と図示です。ついでJPVOLでマスプロパティを計算します。そして行番号2000のサブルーチンで図形特性のプリントを行なわせています。
- QJVOLはこのモデルの表面積、体積を返します。QJGCENは重心位置を返します。QJGINTは世界座標のx、y、z軸回りで計算した慣性モーメントを返します。QJAXISは、この慣性モーメントを元に主軸ベクトルの方向を計算して返します。そこで、モデルを平行移動させ、重心を世界座標の原点に移して、再度、図形特性を計算しました。
10 PRINT "GEOMAP Demonstration Program"
20 PRINT "--- Calculation of Mass Property ---"
30 DIM BSIZE(3,5),NAME$(5)
40 DIM ORIGIN(3),XAXIS(3),YAXIS(3),ZAXIS(3)
50 DIM PAXIS(3,3),GCEN(3),GINT(3,3)
60 READ BSIZE : REM ------ DATA FOR BSIZE ------
70 DATA 20 15 5, 20 15 5, 10 15 15, 30 8 8, 3*20
80 READ NAME$ : REM ------ NAMING FOR BODIES ------
90 DATA "A1","A2","A3","A4","A5"
100 REM ============================== DPCAM
110 CAM(1)=150 : CAM(2)=100 : CAM(3)=90 : TH=0.8
120 DPWIND 0,0,100. : DPCAM CAM,TH
130 CMINIT : REM ===================== PCUBE
140 FOR I=1 TO 5
150 PCUBE NAME$(I), BSIZE(1,I), BSIZE(2,I), BSIZE(3,I)
160 NEXT I
170 REM ==================== PGDIS AND PUNI
180 DIS(1)=-15: DIS(3)=5 : PGDIS "A1",,DIS
190 DIS(3)=-5 : PGDIS "A2",,DIS
200 PUNI "A3","A1","A2"
210 DIS(1)=-20 : DIS(3)=0 : PGDIS "A3",,DIS
220 PUNI "A4","A3"
230 DIS(1)=-25 : PGDIS "A4",,DIS
240 PUNI "A5","A4"
250 JPVOL "A5","JJ"
260 GOSUB 1000 : GOSUB 2000
270 PAUSE
280 DIS(1)=-GCEN(1): DIS(2)=-GCEN(2) : DIS(3)=-GCEN(3)
290 PGDIS "A5","A5",DIS
300 JDEL "JJ" : JPVOL "A5","JJ"
310 GOSUB 1000 : GOSUB 2000
320 END
1000 REM =========== DISPLAY WITH COORDINATE AXES
1010 CLS : HFDISP "A5",,4
1020 XL=50
1030 XAXIS(1)=XL:YAXIS(2)=XL:ZAXIS(3)=XL
1040 DPENTX 4
1050 DQMOVE ORIGIN :DQDRAW XAXIS
1060 DQMOVE ORIGIN :DQDRAW YAXIS
1070 DQMOVE ORIGIN :DQDRAW ZAXIS
1080 RETURN
2000 REM =========== PRINT MASS PROPERTY
2010 PRINT "Centre of Gravity"
2020 QJGCEN "JJ", GCEN
2030 PRINT GCEN
2040 PRINT "Principal Axes"
2050 QJAXIS "JJ", PAXIS
2060 FOR I=1 TO 3
2070 PRINT PAXIS(1,I);PAXIS(2,I);PAXIS(3,I)
2080 NEXT I
2090 PRINT "Moment of Inertia"
2100 QJGINT "JJ",GINT
2110 FOR I=1 TO 3
2120 PRINT GINT(1,I);GINT(2,I);GINT(3,I)
2130 NEXT I
2140 PRINT"Volume and Surface Area"
2150 QJVOL "JJ",VOL,AREA
2160 PRINT VOL,AREA
2170 RETURN
2180 END
「実行時のモニターへの出力を記録したログファイルのリスト」
RUN
GEOMAP Demonstration Program
--- Calculation of Mass Property ---
Centre of Gravity
-21.7040 .000000 .000000
Principal Axes
1.00000 .000000 .000000
.000000 1.00000 .000000
.000000 .000000 1.00000
Moment of Inertia
.993962E+07 .000000 .000000
.000000 375344. .000000
.000000 .000000 400344.
Volume and Surface Area
15170.0 5882.00
「ここまでが実行結果」
「これからユーザーのコンソール入力」
LIST -1000
CDIR
CRENAM "JJ","JJJ"
CDIR
JPVOL "A5","JJ"
CDIR
GOTO 310
「重心を原点に移動させた後の計算結果」
Centre of Gravity
-.141624E-05 -.402341E-07 .643746E-07
Principal Axes
1.00000 .000000 .000000
.000000 1.00000 .000000
.000000 .000000 1.00000
Moment of Inertia
.993962E+07 .117187E-01 -.156250E-01
.117187E-01 375344. -.292969E-02
-.156250E-01 -.292969E-02 400344.
Volume and Surface Area
15170.0 5882.00
LOGOFF
目次へ戻る