Chapter 10.1

10.2　例題プログラム QUERY.BAS の解説

このプログラムは、簡単な多面体である６面体を題材として、幾何モデルのデータを取り出して、モニター画面にプリントさせます。この画面出力を、そのままテキストファイルに出力して印刷させたものを、プログラムリストの次に示してあります。

例題に使ったモデルは最も単純は直方体で、x, y, z軸方向の長さが10、15、20で作りました。このモデルは、面数6、辺数12、頂点数8です。全体図形をまずHFDISPで示しておきました。面、辺、頂点数を確かめ易いように隠れ線は点線で図示しました。
コマンドQFEVNを使って面数NF、辺数NE、頂点数NVを求め、それを利用して必要な寸法の配列を DIM文で求めます。行番号190､260､360 がその例です。普通のプログラム言語では、あらかじめ配列の寸法を決めておかなければなりませんが、配列寸法を変数名で宣言できることが BASIC言語の便利なところです。
コマンドQBOXは、モデルに外接する箱の寸法を求めます。当然ながら、モデルの直方体と同寸法です。
PRINT 文では、印刷フォーマットが自由に制御できることが望まれます。この点に関して、NUCE_BASICの PRINT文の機能は丁寧ではありません。きれいな書式で診察させるには、ログファイルをテキストエディタで編集し直します。印刷文字位置の制御は、次の通りです。
1. 最も詰めて数字を印刷するときのアキは、３スペース分です。この内の１スペースは符号に使われます。
2. PRINT文に、配列名だけを引き数として引用すると、その配列の成分数のデータが詰めて印刷されます（行番号170 ）。
3. 変数の区切りにコロン（；）を使うと、詰めて印刷されます（行番号320 ）。
4. 変数をコンマ（，）で区切ってPRINT 文の引き数に並べると、15文字単位でタブが設定されて印刷されます（行番号230)。
5. 改行は PRINT文単位でおこなわれます。コロン（；）で変数をつないだ場合の改行制御は、空白をプリントさせます（行番号330 ）。
二次元の配列を印刷制御をするときの、FOR...NEXT文の使い方に注目してください。行番号 220～240 と、 390～410 とは一重のループですが、行番号 300～340 は二重のループで制御しています。
NUCE_BASICのプリント文は、モニター画面に印刷する PRINTコマンドだけが定義されています。NUCE_BASICでは、作業の記録をログファイルに記録させる LOGON/LOGOFF のコマンドを使いこれからプリンタに印刷します。コマンド LOGONは、NUCE_BASICがダイレクトモードにあるときに、出力ファイル名を指定して呼びます。LOGON を呼んだ後、ユーザーがキーボードから入力したテキストのすべてと、PRINT 文でモニター画面に出力されたテキストのすべてが、指定したファイルに書き込まれます。この書き込みは、LOGOFFコマンドが指定されるまで有効です。次ページに例題プログラムと、それを実行したときの LOGFILEを示してあります。リストの最初に、RUN コマンドが印刷されていて、処理が終わってコマンドモードに戻って LOGOFF を入力させたところまでが、印刷されています。


     10 PRINT "GEOMAP Demonstration Program"

     20 PRINT "---Data Query for a Solid Model---" 

     30 REM ============================== DPCAM

     40 CAM(1)=35: CAM(2)=-25 : CAM(3)=30 : TH=0.8

     50 REM ============================== PCUBE

     60 CMINIT : PCUBE "A",10., 15., 20.

     70 DPWIND 0,0,100. : DPCAM CAM,TH

     80 CLS : HFDISP "A",,2 
     90 REM ============ QUERY NUMBERS OF FACES,EDGES,VERTICES 

    100 QFEVN "A",NF,NE,NV

    110 PRINT "Number of faces=";    NF 

    120 PRINT "Number of edges=";    NE 

    130 PRINT "Number of vertices="; NV 

    140 REM ============ CONTAINER SIZE 

    150 DIM BMIN(3),BMAX(3) 

    160 QBOX "A",BMIN(1),BMAX(1)

    170 PRINT "Box Size" : PRINT BMIN: PRINT BMAX 

    180 REM ============ DATA OF FACES

    190 DIM FAEQ(4,NF)

    200 QFACE "A",FAEQ

    210 PRINT "Data of Faces" 

    220 FOR I=1 TO NF 

    230 PRINT I,FAEQ(1,I),FAEQ(2,I),FAEQ(3,I),FAEQ(4,I) 

    240 NEXT I

    250 REM ============ DATA OF EDGES

    260 DIM IEDGE(6,NE) 

    270 QEDGE "A",IEDGE 

    280 PRINT "Data of Edges" 

    290 PRINT "No. pFace  nFace pVertex  nVertex status"

    300 FOR I=1 TO NE 

    310 FOR J=1 TO 6

    320 PRINT IEDGE(J,I); 

    330 NEXT J : PRINT ,

    340 NEXT I

    350 REM ============ DATA OF VERTICES 

    360 DIM POS(3,NV) 

    370 QVERT "A",POS 

    380 PRINT "Vertex Coordinates"

    390 FOR I=1 TO NV 

    400 PRINT POS(1,I),POS(2,I),POS(3,I)

    410 NEXT I

    420 END


プログラム実行時のモニター出力



RUN 
GEOMAP Demonstration Program

---Data Query for a Solid Model--- 

Number of faces= 6

Number of edges= 12 

Number of vertices= 8 

Box Size

-5.00000  -7.50000  -10.0000

 5.00000   7.50000   10.0000

Data of Faces 

 1              .000000       .000000      -1.00000      -10.0000 

 2              .000000       .000000       1.00000      -10.0000 

 3              .000000       1.00000       .000000      -7.50000 

 4             -1.00000       .000000       .000000      -5.00000 

 5              .000000      -1.00000       .000000      -7.50000 

 6              1.00000       .000000       .000000      -5.00000 

Data of Edges 

No. pFace  nFace pVertex  nVertex status

 1   3   1   1   2   0

 2   4   1   2   3   0

 3   5   1   3   4   0

 4   6   1   4   1   0

 5   2   3   5   6   0

 6   2   4   6   7   0

 7   2   5   7   8   0

 8   2   6   8   5   0

 9   6   3   1   5   16 

 10   3   4   2   6   16

 11   4   5   3   7   16

 12   5   6   4   8   16

Vertex Coordinates

 5.00000        7.50000      -10.0000 

-5.00000        7.50000      -10.0000 

-5.00000       -7.50000      -10.0000 

 5.00000       -7.50000      -10.0000 

 5.00000        7.50000       10.0000 

-5.00000        7.50000       10.0000 

-5.00000       -7.50000       10.0000 

 5.00000       -7.50000       10.0000 

LOGOFF

目次へ戻る

10.2 例題プログラム QUERY.BAS の解説

10.2　例題プログラム QUERY.BAS の解説